GTM Interrupt does not work? | Hitex ShieldBuddy

GTM Interrupt does not work? Jul 13, 2020 16:28:15 GMT

Quote

Post by sora on Jul 13, 2020 16:28:15 GMT

I am trying to understand how GTM interrupt works. I copied the code from the following url into 1 file to run on Arduino IDE:

github.com/Infineon/AURIX_code_examples/tree/master/code_examples/GTM_TOM_Interrupt_1_KIT_TC297_TFT

Here is my file content:

#define ISR_PRIORITY_TOM    1                       /* Interrupt priority number                                    */
#define TOM_FREQ            2.0f                    /* TOM frequency                                                */
#define LED                 &MODULE_P13, 0          /* LED which will be toggled in Interrupt Service Routine (ISR) */

IfxGtm_Tom_Timer g_timerDriver;                     /* TOM driver                                                   */

/* Macro to define the Interrupt Service Routine. */
IFX_INTERRUPT(interruptGtmTom, 0, ISR_PRIORITY_TOM);

void interruptGtmTom(void)
{
    IfxGtm_Tom_Timer_acknowledgeTimerIrq(&g_timerDriver);                       /* Clear the timer event            */
    IfxPort_togglePin(LED);                                                     /* Toggle the LED                   */
}

/* This function initializes the TOM */
void initGtmTom(void)
{
    IfxGtm_enable(&MODULE_GTM); /* Enable GTM */

    IfxGtm_Tom_Timer_Config timerConfig;                                        /* Timer configuration              */
    IfxGtm_Tom_Timer_initConfig(&timerConfig, &MODULE_GTM);                     /* Initialize timer configuration   */

    timerConfig.base.frequency       = TOM_FREQ;                                /* Set timer frequency              */
    timerConfig.base.isrPriority     = ISR_PRIORITY_TOM;                        /* Set interrupt priority           */
    timerConfig.base.isrProvider     = IfxSrc_Tos_cpu0;                         /* Set interrupt provider           */
    timerConfig.tom                  = IfxGtm_Tom_1;                            /* Define the timer used            */
    timerConfig.timerChannel         = IfxGtm_Tom_Ch_0;                         /* Define the channel used          */
    timerConfig.clock                = IfxGtm_Tom_Ch_ClkSrc_cmuFxclk3;          /* Define the CMU clock used        */

    IfxGtm_Cmu_enableClocks(&MODULE_GTM, IFXGTM_CMU_CLKEN_FXCLK);               /* Enable the CMU clock             */
    IfxGtm_Tom_Timer_init(&g_timerDriver, &timerConfig);                        /* Initialize the TOM               */

    IfxPort_setPinModeOutput(LED, IfxPort_OutputMode_pushPull, IfxPort_OutputIdx_general);  /* Set pin mode         */

    IfxGtm_Tom_Timer_run(&g_timerDriver); /* Start the TOM */
}

void setup() {
  // put your setup code for core 0 here, to run once:
    initGtmTom();

}

void loop() {
  // put your main code for core 0 here, to run repeatedly:

}

When I check interruptGtmTom, there is nothing happened. What am I doing wrong here? How does GTM interact with interrupt?

GTM Interrupt does not work? Jul 14, 2020 8:46:25 GMT

Quote

Post by Admin on Jul 14, 2020 8:46:25 GMT

Unfortunately you cannot use the iLLD approach to using the GTM from within the ShieldBuddy Arduino IDE add-in. The Arduino environment configures the GTM clocks in a special way to give the familiar Arduino functions. To use the GTM in the way you seem to want, you need to use the Hightec Eclipse IDE or better still, the Infineon BIFACES Eclipse and the iLLD drivers. The InitialiseTimerChannel() function uses the GTM ATOM system to generate periodic interrupts, if that is what you need.

/*** Don't worry, the normal Arduino setup() and loop() are below this block! ***/
//#pragma GCC optimize "-O0"

/* LMU uninitialised data */
StartOfUninitialised_LMURam_Variables
/* Put your LMU RAM fast access variables that have no initial values here e.g. uint32 LMU_var; */
EndOfUninitialised_LMURam_Variables

/* LMU uninitialised data */
StartOfInitialised_LMURam_Variables
/* Put your LMU RAM fast access variables that have an initial value here e.g. uint32 LMU_var_init = 1; */
EndOfInitialised_LMURam_Variables

/* If you do not care where variables end up, declare them here! */

void UserTimer2Handler(int i)
{

digitalWrite(13,!digitalRead(13));

}

void UserTimer3Handler(int i)
{

digitalWrite(12,!digitalRead(12));
}

void UserTimer0Handler(int i)
{

digitalWrite(11,!digitalRead(11));
}

void UserTimer4Handler(int i)
{

digitalWrite(10,!digitalRead(10));
}

/*** Core 0 ***/

void setup() {
// put your setup code for core 0 here, to run once:

// Setup output pins
pinMode(13,OUTPUT);
pinMode(12,OUTPUT);
pinMode(11,OUTPUT);
pinMode(10,OUTPUT);

// Set user handlers
TimerChannelConfig[2].user_inthandler = UserTimer2Handler;
TimerChannelConfig[3].user_inthandler = UserTimer3Handler;
TimerChannelConfig[0].user_inthandler = UserTimer0Handler;

// Initialise general timer channels
InitialiseTimerChannel(2);
InitialiseTimerChannel(3);
InitialiseTimerChannel(0);

// Set general timers base clock to 12.5MHz
CMU_CLK4_val = 7; // Get a 12.5MHz CMU_CLK4

setupGtmClocks(); // FX_CLK0 => 10ns
setupGtmTbu(); // TBU_CH0 counts CMU_CLK0,TBU_CH1 counts CMU_CLK1

// Set period of timers
SetTimerChannelPeriod(2,12500000); // 1 sec
SetTimerChannelPeriod(3,0x4000);
SetTimerChannelPeriod(0,100000);

}

void loop() {
// put your main code for core 0 here, to run repeatedly:

}

/*** Core 1 ***/

/* CPU1 Uninitialised Data */
StartOfUninitialised_CPU1_Variables
/* Put your CPU1 fast access variables that have no initial values here e.g. uint32 CPU1_var; */
EndOfUninitialised_CPU1_Variables

/* CPU1 Initialised Data */
StartOfInitialised_CPU1_Variables
/* Put your CPU1 fast access variables that have an initial value here e.g. uint32 CPU1_var_init = 1; */
EndOfInitialised_CPU1_Variables

void setup1() {
// put your setup code for core 1 here, to run once:

// Create a periodic interrupt for core 1
InitialiseTimerChannel(4);

TimerChannelConfig[4].user_inthandler = UserTimer4Handler;
SetTimerChannelPeriod(4,100000);

}

void loop1() {
// put your main code for core 1 here, to run repeatedly:

}

/*** Core 2 ***/

/* CPU2 Uninitialised Data */
StartOfUninitialised_CPU2_Variables
/* Put your CPU2 fast access variables that have no initial values here e.g. uint32 CPU2_var; */
EndOfUninitialised_CPU2_Variables

/* CPU2 Initialised Data */
StartOfInitialised_CPU2_Variables
/* Put your CPU2 fast access variables that have an initial value here e.g. uint32 CPU2_var_init = 1; */
EndOfInitialised_CPU2_Variables

void setup2() {
// put your setup code for core 2 here, to run once:

}

void loop2() {
// put your main code for core 2 here, to run repeatedly:

}